Zoradiť údaje v tabuľke

[Dušan]

Mám úplné jednoduchú konečnú tabuľku. Do nej sa pomocou vzorca sťahujú údaje z iných zdrojov napr. iných tabuliek, ktoré sa priebežne dopĺňajú. Dá sa nastaviť v Excely automatické zoraďovanie konečnej tabuľky podľa niektorého stĺpca napr. od najmenšieho ...tak aby som to nemusel robiť mechanický (vybrať tabuľku/údaje/zoradiť/zoradiť podľa stĺpca C/od najmenšieho po najväčšie) za každým keď sa údaje v tabuľke zmenia? Teda po každej zmene údajov by sa tabuľka zoradila podľa istých nastavených kritérií.

Dušan

[Palo-admin]

Bez použitia makra nie.
S makrom áno, pri použití typu makra, ktoré stráži akúkoľvek zmenu v bunkách aktívneho listu (Worksheet_Change).

Kód: Vybrať všetko

Private Sub Worksheet_Change(ByVal Target As Range)

On Error GoTo xErr:
    If Not Intersect(Target, Range("C:C")) Is Nothing Then
        Application.EnableEvents = False
            Call Sort_podla_C               ' volaj sortovanie pri zmene v C
        Application.EnableEvents = True
    End If
   
    Exit Sub
   
xErr:
     Application.EnableEvents = True
End Sub



Kód: Vybrať všetko

Sub Sort_podla_C()
    Range("C1").Select
    Range("A:C").Sort Key1:=Range("C1"), Order1:=xlAscending, Header:= _
        xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
        DataOption1:=xlSortTextAsNumbers
End Sub


!!! Môže to byť však kontraproduktívne, pri veľkom počte údajov.
To by som asi už radšej volal makro Sort_podla_C cez nejaké tlačidlo.

Palo

[marian73]

Ahoj potreboval by som poradiť s tabuľkou na zoradenie údajov.
Skúsil som použiť makro v tomto príspevku, ale mi to nefunguje.
Prikladám aj tabuľku.
Ďakujem za pomoc ak sa podarí.

[Palo-admin]

Ahoj potreboval by som poradiť s tabuľkou na zoradenie údajov.
Skúsil som použiť makro v tomto príspevku, ale mi to nefunguje.
Prikladám aj tabuľku.
Ďakujem za pomoc ak sa podarí.

Ahoj Marian

S jednou drobnou úpravou (voľný riadok medzi dátum a hlavičku) som urobil makro so sortovaním nad zapnutým auto filtrom
( v hlavičke totiž používaš zlúčené bunky).

Kód: Vybrať všetko

Sub MySort_Asc()
    Call MySort_AscDesc("Vzostupne")
End Sub

Sub MySort_Desc()
    Call MySort_AscDesc("Zostupne")
End Sub

Sub MySort_AscDesc(xSmer As String)
    Dim xLastRow As Integer, xSortType
   
    xLastRow = Range("M60000").End(xlUp).Row

    If xSmer = "Vzostupne" Then
        xSortType = xlAscending
    Else
        xSortType = xlDescending
    End If
   
    Range("M5").Select
    If ActiveSheet.AutoFilterMode = False Then
        Selection.AutoFilter
    End If

    ActiveSheet.AutoFilter.Sort.SortFields.Clear
    ActiveSheet.AutoFilter.Sort.SortFields.Add Key:=Range _
        ("M5:M" & xLastRow), SortOn:=xlSortOnValues, Order:=xSortType, DataOption:= _
        xlSortTextAsNumbers
       
    With ActiveSheet.AutoFilter.Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub


P.

[marian73]

Ďakujem za pomoc